The parametric equations of the unit sphere  x = Cos[θ] Sin[ϕ],  y = Sin[θ] Sin[ϕ], z = Cos[ϕ] with 0≤ θ ≤2π,  0≤ ϕ ≤ π are used in ParametricPlot3D to produce a graph of the unit sphere.

ParametricPlot3D[{Cos[θ]Sin[ϕ],Sin[θ]Sin[ϕ],Cos[ϕ]},{θ,0,2Pi},{ϕ,0,Pi}]

One can use Manipulate[] to explore the efect of the domains for the variables θ and ϕ.

Manipulate[ParametricPlot3D[{Cos[θ]Sin[ϕ],Sin[θ]Sin[ϕ],Cos[ϕ]},{θ,0,tt},{ϕ,0,ff},PlotRange->{{-1.2,1.2},{-1.2,1.2},{-1.2,1.2}},ImageSize->250],{{tt,Pi},0.1,2 Pi,ControlPlacement->Top},{{ff,Pi/2},0.1,Pi,ControlPlacement->Top}]

There are many options that one can use in ParametricPlot3D to produce a nicer graph.

Options[ParametricPlot3D]

The option Mesh is related to  coordinate curves.  Recall the concept of coordinate curves for the unit sphere  

x = Cos[θ] Sin[ϕ],  y = Sin[θ] Sin[ϕ], z = Cos[ϕ] with 0≤ θ ≤ 2π,  0≤ ϕ ≤ π.  

There are two families of coordinate curves. 

The first family consists of the curves obtained by keeping θ constant and letting ϕ vary from 0 to π.  In this way we obtain a family of semi-circles. These curves are colored dark red in the plot below. 

The second family consists of the curves obtained by keeping ϕ constant and letting θ vary from 0 to 2π.  In this way we obtain a family of horiontal circles. These circles are colored dark green in the plot below.

ParametricPlot3D[{Cos[θ]Sin[ϕ],Sin[θ]Sin[ϕ],Cos[ϕ]},{θ,0,2Pi},{ϕ,0,Pi},PlotPoints->{129,65},Mesh->{11,11},MeshStyle->{{Thickness[0.005],RGBColor[0.5,0,0]},{Thickness[0.005],RGBColor[0,0.5,0]}},PlotStyle->{Opacity[0.8]}]

Notice that we asked Mathematica to plot 11 coordinate curves in each family. It appears that one dark red coordinate line is missing. The reason for that is that the domain for θ is the interval [0,2π] and Mathematica chooses 11 equidistant values in the open interval (0,2π).  Those are the values (π/6), (π/3),(π/2),((2 π)/3),((5π)/6), π,((7π)/6),((4π)/3),((3π)/2),((5π)/3),((11π)/6).  Similarly, the dark green circles are plotted for the valus of  ϕ equal to  (π/12), (π/6),(π/4),(π/3),((5π)/12),(π/2),((7π)/12),((2π)/3),((3π)/4),((5π)/6),((11π)/12).

The values 0 and 2π for θ are considered boundary values and to plot the corresponding coordinate curves we do the following.

ParametricPlot3D[{Cos[θ]Sin[ϕ],Sin[θ]Sin[ϕ],Cos[ϕ]},{θ,0,2Pi},{ϕ,0,Pi},PlotPoints->{129,129},Mesh->{11,11},BoundaryStyle->Directive[Thick,Red],MeshStyle->{{Thickness[0.005],RGBColor[0.5,0,0]},{Thickness[0.005],RGBColor[0,0.5,0]}},PlotStyle->{Opacity[0.8]}]

To better understand the function BoundaryStyle look at

ParametricPlot3D[{Cos[θ]Sin[ϕ],Sin[θ]Sin[ϕ],Cos[ϕ]},{θ,Pi/6,11Pi/6},{ϕ,Pi/6,5Pi/6},PlotPoints->{129,129},Mesh->{11,11},BoundaryStyle->Directive[Thick,Red],MeshStyle-> {{Thickness[0.005],RGBColor[0.5,0,0]},{Thickness[0.005],RGBColor[0,0.5,0]}},PlotStyle->{Opacity[0.8]}]

Let us now plot a function of two variables as a parametrized surface.

ParametricPlot3D[ {x,y ,(x^2)+(y^2)},{x,-1,1},{y,-1,1},PlotRange->{{-2.2,2.2},{-2.2,2.2},{-0.2,2.2}},ImageSize->250]

In vector notation the equation for this surface is  x i + u j +(x^2+y^2) k.

It is usefull to notice that we can replace the coordinate vectors i, j, k, by any three mutually orthogonal unit vectors and we will get a differently positioned congruent plot.

uu=(1/(Sqrt[3])){1,1,1}; vv=(1/(Sqrt[2])){0,1,-1};ww=(1/(Sqrt[6])){2,-1,-1}

ParametricPlot3D[ x uu+y vv+((x^2)+(y^2))ww,{x,-1,1},{y,-1,1},PlotRange->{{-2.2,2.2},{-2.2,2.2},{-2.2,2.2}},ImageSize->250]

Another example:

ParametricPlot3D[ {x,y,(Sin[x] Cos[y])},{x,-Pi,Pi},{y,-Pi,Pi},PlotRange->{{-3.2,3.2},{-3.2,3.2},{-3.2,3.2}},ImageSize->250]

ParametricPlot3D[ x uu+y vv+(Sin[x] Cos[y])ww,{x,-Pi,Pi},{y,-Pi,Pi},PlotRange->{{-3.2,3.2},{-3.2,3.2},{-3.2,3.2}},ImageSize->250]

Next we present a different way to parametrize the paraboloid z = x^2+y^2.

The level curves of this paraboloid are circles. At level z the radius of the circle is (Sqrt[z]).  Thus, the parametric equations of this paraboloid are x = (Sqrt[z])Cos[θ], y =   (Sqrt[z])Sin[θ], z = z.

ParametricPlot3D[ {(Sqrt[z])Cos[θ],(Sqrt[z])Sin[θ],z},{θ,0,2 Pi},{z,0,2},PlotRange->{{-2.2,2.2},{-2.2,2.2},{-0.2,2.2}},ImageSize->250]

In words, the above parametric equations are saying that at level  z  we are plotting the circle with radius (Sqrt[z]).

But, we can choose to plot the circle of radius, say 2 + Sin[z] at level z. In this way we get the surface which is obtained by rotating  the graph of  x = 2 + Sin[z]  about the z-axis.

ParametricPlot3D[ {(2+Sin[ z])Cos[θ],(2+Sin[z])Sin[θ],z},{θ,0,2 Pi},{z,-Pi,Pi},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-Pi,Pi }},ImageSize->250]

In fact we have rotated the graph of  x = 2 Sin[z].

ParametricPlot3D[ {(2+Sin[ z])Cos[θ],(2+Sin[z])Sin[θ],z},{θ,0,2 Pi},{z,-2Pi,2Pi},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2Pi,2Pi }},ImageSize->250]

Manipulate[ParametricPlot3D[ {(2+Sin[ z])Cos[θ],(2+Sin[z])Sin[θ],z},{θ,0,tt},{z,-2Pi,2Pi},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2Pi,2Pi }},ImageSize->250],{{tt,Pi},0.1,2 Pi,ControlPlacement->Top}]

Let us add a “helix” on this graph.

Show[ParametricPlot3D[ {(2+Sin[ z])Cos[θ],(2+Sin[z])Sin[θ],z},{θ,0,2 Pi},{z,-2Pi,2Pi},PlotStyle->{Opacity[0.7]},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2Pi,2Pi }},ImageSize->250],
ParametricPlot3D[ {(2+Sin[t])Cos[2 t],(2+Sin[t])Sin[2 t],t},{t,-2Pi,2Pi},PlotStyle->{Thickness[0.008],Blue},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2Pi,2Pi }},ImageSize->250]]

And finally, let us rotate the unit circle centered at (3,0,0) in the xz-plane about z-axis.

ParametricPlot3D[ {Cos[θ](3+Cos[ϕ]),Sin[θ](3+Cos[ϕ]),Sin[ϕ]},{θ,0,2 Pi},{ϕ,0,2 Pi},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2.2,2.2}},ImageSize->250]

To undersand the role of the variables θ and ϕ it might be usefull to Manipulate[] this plot.

Manipulate[ParametricPlot3D[ {Cos[θ](3+Cos[ϕ]),Sin[θ](3+Cos[ϕ]),Sin[ϕ]},{θ,0,tt},{ϕ,0,ff},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2.2,2.2}},ImageSize->250],{{tt,Pi},0+.1,2 Pi,ControlPlacement->Top},{{ff,Pi},0+.1,2 Pi,ControlPlacement->Top}]

And, adding a “helix” would be a nice decoration.

Show[ParametricPlot3D[ {Cos[θ](3+Cos[ϕ]),Sin[θ](3+Cos[ϕ]),Sin[ϕ]},{θ,0,2 Pi},{ϕ,0,2 Pi},PlotStyle->{Opacity[0.7]},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2.2,2.2}},ImageSize->250] ,ParametricPlot3D[ {Cos[t](3+Cos[6 t]),Sin[t](3+Cos[6 t]),Sin[6 t]},{t,0,2 Pi},PlotStyle->{Thickness[0.008],Blue},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2.2,2.2}},ImageSize->250] ]

Manipulate[
Show[ParametricPlot3D[ {Cos[θ](3+Cos[ϕ]),Sin[θ](3+Cos[ϕ]),Sin[ϕ]},{θ,0,2 Pi},{ϕ,0,2 Pi},PlotStyle->{Opacity[0.7]},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2.2,2.2}},ImageSize->250] ,ParametricPlot3D[ {Cos[t](3+Cos[nn t]),Sin[t](3+Cos[nn t]),Sin[nn t]},{t,0,2 Pi},PlotStyle->{Thickness[0.008],Blue},PlotRange->{{-4.2,4.2},{-4.2,4.2},{-2.2,2.2}},ImageSize->250] ],
{nn,{1,2,3,4,5,6,7,8,9,10,11,12},Setter,ControlPlacement->Top}
]