Problem 4

Area

2 Integrate[b (Sqrt[1-(x/a)^2]),{x,-a,a}]

Solve[a b π==Pi,b]

Show[Table[ParametricPlot[{{a Cos[t],(1/a)Sin[t]},{(1/a) Cos[t],a Sin[t]}},{t,0,2 Pi},PlotStyle->{{Thickness[0.001],Hue[a]},{Thickness[0.001],Hue[a]}}],{a,0.05,1,.05}],Plot[{(1/(2x)),-(1/(2x))},{x,-6,6},PlotStyle->{{Thickness[0.003],RGBColor[0,0,1]},{Thickness[0.003],RGBColor[0,0,1]}},Exclusions->{0},PlotRange->{{-6,6},{-6,6}},AspectRatio->Automatic],PlotRange->{{-5,5},{-5,5}},AspectRatio->Automatic,ImageSize->400]

Length

The length of the ellipse is given by the following integral.

(* Integrate[(Sqrt[(a^2) ((Sin[t])^2)+(b^2)((Cos[t])^2)]),{t,0,2 Pi}] *)

To help Mathematica evaluate this integral we use the symmetry of the ellipse

4 Integrate[(Sqrt[(a^2) ((Sin[t])^2)+(b^2)((Cos[t])^2)]),{t,0,Pi/2}]

To help further we tell Mathematica that the coefficients a and b are positive.

4 Integrate[(Sqrt[(a^2) ((Sin[t])^2)+(b^2)((Cos[t])^2)]),{t,0,Pi/2},Assumptions->And[a>0,b>0]]

When a=b then the ellipse is a circle with the radius a.

EllipticE[0]

Clearly the length of the ellipse stays the same when a and b interchange the roles. But Mathematica does not know that

4 a EllipticE[1-((b^2)/(a^2))]

and

4 b EllipticE[1-((a^2)/(b^2))]

equal for all positive a and b.

FullSimplify[4 a EllipticE[1-((b^2)/(a^2))]-4 b EllipticE[1-((a^2)/(b^2))],And[a>0,b>0]]

Try plotting:

Plot3D[-4 b EllipticE[1-((a^2)/(b^2))]+4 a EllipticE[1-((b^2)/(a^2))],{a,0,2},{b,0,2}]

?EllipticE

Try another calculation for the length.

2 Integrate[(Sqrt[(a^2) ((Sin[t])^2)+(b^2)((Cos[t])^2)]),{t,0,Pi},Assumptions->And[a>0,b>0]]

This is the third equivalent expression for the lenght of an ellipse with axes a and b.

Replacing b/a with x in

EllipticE[1-((b^2)/(a^2))]

we get the function

Plot[EllipticE[1 -(x^2)],{x,0,10},PlotRange->{0,5}]

This function clearly has an inverse. Let us find it.

Solve[EllipticE[1-(y^2)]==x,y]

The following graph points out that the last two functions are inverses of each other

Show[Plot[{EllipticE[1-(x^2)],x},{x,0,10},PlotStyle->{{Thickness[0.002],Blue} ,{Thickness[0.002],Black}}],Plot[{(Sqrt[1-(EllipticE^((-1)))[x]]) },{x,1,10},PlotStyle->{{Thickness[0.002],Red}}],Axes->True,AxesOrigin->{0,0}, PlotRange->{{0,5},{0,5}},AspectRatio->1,ImageSize->300]

Now solve for b:

Solve[4 a EllipticE[1-((b^2)/(a^2))]==2 Pi,b]

Since b is positive we use the second formula for b.  Below I show several “wide” ellipses that have circumference equal to 2π.

FullSimplify[(Sqrt[(a^2)-(a^2) (EllipticE^((-1)))[(π/(2 a))]]),a>0]

Show[Table[ParametricPlot[{a Cos[t],a(Sqrt[1-(EllipticE^((-1)))[(Pi/(2 a))]])Sin[t]},{t,0,2 Pi}],{a,1,Pi/2,.05}],PlotRange->{{-Pi/2,Pi/2},{-Pi/2,Pi/2}}]

Here I show many 50 ellipses that have circumference 2π. 25 of these ellipses are wide and 25 are tall.

Show[Table[ParametricPlot[{{a Cos[t],a(Sqrt[1-(EllipticE^((-1)))[(Pi/(2 a))]])Sin[t]},{a(Sqrt[1-(EllipticE^((-1)))[(Pi/(2 a))]]) Cos[t],a Sin[t]}},{t,0,2 Pi},PlotStyle->{{Thickness[0.001],Hue[a]},{Thickness[0.001],Hue[a]}}],{a,0.05,1,.05}],Ticks->{{-Pi/2,-1,0,1,Pi/2},{-Pi/2,-1,0,1,Pi/2}},PlotRange->{{-Pi/2,Pi/2},{-Pi/2,Pi/2}},ImageSize->400]

Show[Table[ParametricPlot[{{a Cos[t],a(Sqrt[1-(EllipticE^((-1)))[(Pi/(2 a))]])Sin[t]},{a(Sqrt[1-(EllipticE^((-1)))[(Pi/(2 a))]]) Cos[t],a Sin[t]}},{t,0,2 Pi},PlotStyle->{{Thickness[0.001],Hue[a]},{Thickness[0.001],Hue[a]}}],{a,0.05,1,.05}],Axes->False,Frame-> True, FrameTicks->{{-Pi/2,-1,0,1,Pi/2},{-Pi/2,-1,0,1,Pi/2},{},{}},PlotRange->{{-Pi/2,Pi/2},{-Pi/2,Pi/2}},ImageSize->400]