Classification of Quadratic Forms

Quadratic Forms on (ℝ^2)

Eigenvalues: 0 (zero quadratic form)

Eigenvalues: 0, 1 (positive semi-definite quadratic form)

In this case Q(x) = ((((Subscript[x, 2])))^2)

Plot3D[(y^2),{x,-3,3},{y,-3,3}]

(I) The set {x ∈ (ℝ^2):Q(x) =1} is the union of two parallel lines (Subscript[x, 2])=1 and (Subscript[x, 2])=-1.

Plot3D[{1,(y^2)},{x,-3,3},{y,-3,3},Mesh->False,PlotStyle->{{},{Opacity[0.75]}}]

ContourPlot[(y^2),{x,-3,3},{y,-3,3},Contours->{1},ContourShading->False]

(II) The set {x ∈ (ℝ^2):Q(x) =0} is the (Subscript[x, 1])-axis

ContourPlot[(y^2),{x,-3,3},{y,-3,3},Contours->{0.00001},ContourShading->False]

(III) The set {x ∈ (ℝ^2):Q(x) =-1} is empty.

Eigenvalues: 1, 1 (positive definite quadratic form)

In this case Q(x) = ((((Subscript[x, 1])))^2)+ ((((Subscript[x, 2])))^2)

Plot3D[(x^2)+(y^2),{x,-3,3},{y,-3,3},BoxRatios->{1,1,2}]

(I) The set {x ∈ (ℝ^2):Q(x) =1} is the unit circle in (ℝ^2): ((((Subscript[x, 1])))^2)+ ((((Subscript[x, 2])))^2)=1.

Plot3D[{1,(x^2)+(y^2)},{x,-3,3},{y,-3,3},Mesh->False,PlotStyle->{{},{Opacity[0.75]}},PlotRange->{0,6},BoxRatios->{1,1,3/2},ClippingStyle->None]

ContourPlot[(x^2)+(y^2),{x,-3,3},{y,-3,3},Contours->{1},ContourShading->False]

(II) The set {x ∈ (ℝ^2):Q(x) =0} is the set which consists of only one point, the origin (0,0).

ContourPlot[(x^2)+(y^2),{x,-3,3},{y,-3,3},Contours->{0.0001},ContourShading->False]

(III) The set {x ∈ (ℝ^2):Q(x) =-1} is the empty set.

Eigenvalues: 0, -1 (negative semi-definite quadratic form)

Eigenvalues: -1, -1 (negative definite quadratic form)

Eigenvalues: -1, 1 (indefinite quadratic form)

In this case Q(x) = -((((Subscript[x, 1])))^2)+ ((((Subscript[x, 2])))^2)

Plot3D[-(x^2)+(y^2),{x,-3,3},{y,-3,3},BoxRatios->{1,1,2}]

(I) The set {x ∈ (ℝ^2):Q(x) =1} is the hyperbola in (ℝ^2): -((((Subscript[x, 1])))^2)+ ((((Subscript[x, 2])))^2)=1.

Plot3D[{1,-(x^2)+(y^2)},{x,-3,3},{y,-3,3},Mesh->False, PlotStyle->{{Opacity[0.5]},{Opacity[0.7]}},BoxRatios->{1,1,2},ClippingStyle->None]

ContourPlot[-(x^2)+(y^2),{x,-3,3},{y,-3,3},Contours->{1},ContourShading->False]

(II) The set {x ∈ (ℝ^2):Q(x) =0} is the set which consists of two lines, (Subscript[x, 1])=(Subscript[x, 2]) and (Subscript[x, 1])=-(Subscript[x, 2]).

Plot3D[{0,-(x^2)+(y^2)},{x,-3,3},{y,-3,3},Mesh->False, PlotStyle->{{Opacity[0.5]},{Opacity[0.7]}},BoxRatios->{1,1,2},ClippingStyle->None]

ContourPlot[-(x^2)+(y^2),{x,-3,3},{y,-3,3},Contours->{0},ContourShading->False]

(III) The set {x ∈ (ℝ^2):Q(x) =-1} is the hyperbola in (ℝ^2): ((((Subscript[x, 1])))^2)- ((((Subscript[x, 2])))^2)=1..

Plot3D[{-1,-(x^2)+(y^2)},{x,-3,3},{y,-3,3},Mesh->False, PlotStyle->{{Opacity[0.5]},{Opacity[0.7]}},BoxRatios->{1,1,2},ClippingStyle->None]

ContourPlot[-(x^2)+(y^2),{x,-3,3},{y,-3,3},Contours->{-1},ContourShading->False]

Quadratic Forms on (ℝ^3)

Eigenvalues: 0 (zero quadratic form)

In this case Q(x) = 0

(I) The set {x ∈ (ℝ^3):Q(x) =1} is empty.

(II) The set {x ∈ (ℝ^3):Q(x) =0} is (ℝ^3).

(III) The set {x ∈ (ℝ^3):Q(x) =-1} is empty.

Eigenvalues: 0, 0, 1 (positive semi-definite quadratic form)

In this case Q(x) = ((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1} is the union of two parallel planes (Subscript[x, 3])=1 and (Subscript[x, 3])=-1 ((Subscript[x, 1]),(Subscript[x, 2]) are arbitrary).

ContourPlot3D[(z^2),{x,-5,5},{y,-5,5},{z,-5,5},Contours->{1},Mesh->False,ContourStyle->{Opacity[0.5]},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the (Subscript[x, 1])(Subscript[x, 2])-plane.

ContourPlot3D[(z^2),{x,-5,5},{y,-5,5},{z,-5,5},Contours->{0.0001},Mesh->False,ContourStyle->{Opacity[0.5]},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

(III) The set {x ∈ (ℝ^3):Q(x) =-1} is the empty set.

Eigenvalues: 0, 1, 1 (positive semi-definite quadratic form)

In this case Q(x) = ((((Subscript[x, 2])))^2)+((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1}  is the circular cylinder parallel to (Subscript[x, 1])-axis whose directrix is the unit circle in (Subscript[x, 2])(Subscript[x, 3])-plane.

ContourPlot3D[(y^2)+(z^2),{x,-3,3},{y,-3,3},{z,-3,3},Contours->{1},Mesh->False,ContourStyle->{Opacity[0.5]},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the (Subscript[x, 1])-axis.

ContourPlot3D[(y^2)+(z^2),{x,-3,3},{y,-3,3},{z,-3,3},Contours->{0.0001},Mesh->False,ContourStyle->{Opacity[0.5]},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

(III) The set {x ∈ (ℝ^3):Q(x) =-1} is the empty set.

Eigenvalues: 1, 1, 1 (positive definite quadratic form)

In this case Q(x) = ((((Subscript[x, 1])))^2)+ ((((Subscript[x, 2])))^2)+((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1} is the unit sphere.

ContourPlot3D[(x^2)+(y^2)+(z^2),{x,-3,3},{y,-3,3},{z,-3,3},Contours->{1},Mesh->False,ContourStyle->{Opacity[0.5]},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the set which consists of only one point, the origin (0,0,0).

(III) The set {x ∈ (ℝ^3):Q(x) =-1} is the empty set.

Eigenvalues: 0, 0, -1 (negative semi-definite quadratic form)

In this case Q(x) = -((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1} is the empty set.

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the (Subscript[x, 1])(Subscript[x, 2])-plane.

(III) The set {x ∈ (ℝ^3):Q(x) =-1} is the union of two parallel planes  (Subscript[x, 3])=1 and (Subscript[x, 3])=-1 ((Subscript[x, 1]),(Subscript[x, 2]) are arbitrary).

Eigenvalues: 0, -1, -1 (negative semi-definite quadratic form)

In this case Q(x) = - ((((Subscript[x, 2])))^2)-((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1} is the empty set.

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the (Subscript[x, 1])-axis.

(III) The set {x ∈ (ℝ^3):Q(x) =-1}  is the circular cylinder parallel to (Subscript[x, 1])-axis whose directrix is the unit circle in (Subscript[x, 2])(Subscript[x, 3])-plane.

Eigenvalues: -1, -1, -1 (negative definite quadratic form)

In this case Q(x) =- ((((Subscript[x, 1])))^2)- ((((Subscript[x, 2])))^2)-((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1} is the empty set.

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the empty set.

(III) The set {x ∈ (ℝ^3):Q(x) =-1} is the unit sphere.

Eigenvalues: -1, 1, 1 (indefinite quadratic form)

In this case Q(x) = -((((Subscript[x, 1])))^2)+ ((((Subscript[x, 2])))^2)+((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1} is the one-sheet hyperboloid. This surface can be visualized as one branch of the hyperbola - ((((Subscript[x, 1])))^2)+((((Subscript[x, 3])))^2)=1 rotating about (Subscript[x, 1])-axis.

ContourPlot3D[-(x^2)+(y^2)+(z^2),{x,-5,5},{y,-5,5},{z,-5,5},Contours->{1},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

Manipulate[Show[ParametricPlot3D[{Sinh[s],Cosh[s] Sin[θ],Cosh[s] Cos[θ]},{s,-5,5},{θ,0,tt},PlotPoints->{50,64},Mesh->False],ParametricPlot3D[{Sinh[s],Cosh[s] Sin[tt],Cosh[s] Cos[tt]},{s,-5,5},PlotPoints->{50},PlotStyle->{{Thickness[0.01],RGBColor[1,0,0]}}],PlotRange->{{-5,5},{-5,5},{-5,5}},AxesLabel->{x,y,z}],{tt,0.01,2Pi}]

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the circular cone whose axes is the (Subscript[x, 1])-axes.

(III) The set {x ∈ (ℝ^3):Q(x) =-1} is the two-sheet hyperboloid.

Eigenvalues: -1, -1, 1 (indefinite quadratic form)

In this case Q(x) = -((((Subscript[x, 1])))^2)- ((((Subscript[x, 2])))^2)+((((Subscript[x, 3])))^2)

(I) The set {x ∈ (ℝ^3):Q(x) =1} is the two-sheet hyperboloid. This surface can be visualized as the hyperbola - ((((Subscript[x, 1])))^2)+((((Subscript[x, 3])))^2)=1 rotating about (Subscript[x, 3])-axis.

ContourPlot3D[-(x^2)-(y^2)+(z^2),{x,-5,5},{y,-5,5},{z,-5,5},Contours->{1},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

Manipulate[Show[ParametricPlot3D[{Sinh[s] Cos[θ],Sinh[s] Sin[θ],Cosh[s]},{s,-5,5},{θ,0,tt},PlotPoints->{50,64},Mesh->False],
ParametricPlot3D[{Sinh[s] Cos[θ],Sinh[s] Sin[θ],-Cosh[s]},{s,-5,5},{θ,0,tt},PlotPoints->{50,64},Mesh->False],ParametricPlot3D[{Sinh[s] Cos[tt],Sinh[s] Sin[tt],Cosh[s]},{s,-5,5},PlotPoints->{50},PlotStyle->{{Thickness[0.01],RGBColor[1,0,0]}}],ParametricPlot3D[{Sinh[s] Cos[tt],Sinh[s] Sin[tt],-Cosh[s]},{s,-5,5},PlotPoints->{50},PlotStyle->{{Thickness[0.01],RGBColor[1,0,0]}}],PlotRange->{{-5,5},{-5,5},{-5,5}},AxesLabel->{x,y,z}],{tt,0.01,Pi}]

(II) The set {x ∈ (ℝ^3):Q(x) =0} is the circular cone whose axes is the (Subscript[x, 3])-axes.

ContourPlot3D[-(x^2)-(y^2)+(z^2),{x,-5,5},{y,-5,5},{z,-5,5},Contours->{0},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

(II) The set {x ∈ (ℝ^3):Q(x) =-1} is the one-sheet hyperboloid. This surface can be visualized as one branch of the hyperbola ((((Subscript[x, 1])))^2)-((((Subscript[x, 3])))^2)=1 rotating about (Subscript[x, 3])-axis.

ContourPlot3D[-(x^2)-(y^2)+(z^2),{x,-5,5},{y,-5,5},{z,-5,5},Contours->{-1},PlotPoints->{100,100,100},AxesLabel->{x,y,z}]

Manipulate[Show[ParametricPlot3D[{Cosh[s] Cos[θ],Cosh[s] Sin[θ],Sinh[s]},{s,-5,5},{θ,0,tt},PlotPoints->{50,64},Mesh->False],ParametricPlot3D[{Cosh[s] Cos[tt],Cosh[s] Sin[tt],Sinh[s]},{s,-5,5},PlotPoints->{50},PlotStyle->{{Thickness[0.01],RGBColor[1,0,0]}}],PlotRange->{{-5,5},{-5,5},{-5,5}},AxesLabel->{x,y,z}],{tt,0.01,2Pi}]

Fun with Hyperboloid

Options[Graphics3D]

Graphics3D[{{Thickness[0.01],RGBColor[0.7,0.7,0.7],Line[{Cos[#],Sin[#],1}&/@Range[0,2Pi,(Pi/64)]]},{Thickness[0.01],RGBColor[0.7,0.7,0.7],Line[{Cos[#],Sin[#],-1}&/@Range[0,2Pi,(Pi/64)]]},{Line[{{Cos[#],Sin[#],1},{Cos[#],Sin[#],-1}}]&/@Range[0,2Pi,(Pi/48)]}},PlotRange->{{-1.1,1.1},{-1.1,1.1},{-1.1,1.1}}]

Manipulate[Graphics3D[{{Thickness[0.007],RGBColor[0.7,0.7,0.7],Line[{Cos[#],Sin[#],1}&/@Range[0,2Pi,(Pi/64)]]},
{Thickness[0.007],RGBColor[0.7,0.7,0.7],Line[{{0,0,1},{Cos[θ+#],Sin[θ+#],1}}]&/@Range[0,2 Pi,2Pi/2]},{Thickness[0.007],RGBColor[0.7,0.7,0.7],Line[{Cos[#],Sin[#],-1}&/@Range[0,2Pi,(Pi/64)]]},{Thickness[0.005],Opacity[0.95],{Hue[#/(2Pi)],Line[{{Cos[θ+#],Sin[θ+#],1},{Cos[#],Sin[#],-1}}]}&/@Range[0,2Pi,(Pi/16)]}},PlotRange->{{-1.1,1.1},{-1.1,1.1},{-1.1,1.1}}],{θ,0,2Pi}]

Show[Plot3D[3(x^2)-2(y^2),{x,-3,3},{y,-3,3},Mesh->False,PlotStyle->{Opacity[0.6]}],Graphics3D[{Thickness[0.01],Blue,Line[Table[{Cos[t],Sin[t],0},{t,0,2 Pi,(Pi/64)}]]}],Graphics3D[{Thickness[0.01],Red,Line[Table[{Cos[t],Sin[t],3((Cos[t])^2)-2((Sin[t])^2)},{t,0,2 Pi,(Pi/64)}]]}],PlotRange->{{-2,2},{-2,2},{-3,3}},BoxRatios->{1,1,3/2}]

Show[Plot3D[1(x^2)+6 x y+1(y^2),{x,-3,3},{y,-3,3},Mesh->False,PlotStyle->{Opacity[0.6]}],Graphics3D[{Thickness[0.01],Blue,Line[Table[{Cos[t],Sin[t],0},{t,0,2 Pi,(Pi/64)}]]}],Graphics3D[{Thickness[0.01],Red,Line[Table[{Cos[t],Sin[t],1((Cos[t])^2)+6 Cos[t] Sin[t]+1((Sin[t])^2)},{t,0,2 Pi,(Pi/64)}]]}],PlotRange->{{-2,2},{-2,2},{-4,4}},BoxRatios->{1,1,4/2}]

Show[Plot3D[6(x^2)-4 x y+3(y^2),{x,-3,3},{y,-3,3},Mesh->False,PlotStyle->{Opacity[0.6]}],Graphics3D[{Thickness[0.01],Blue,Line[Table[{Cos[t],Sin[t],0},{t,0,2 Pi,(Pi/64)}]]}],Graphics3D[{Thickness[0.01],Red,Line[Table[{Cos[t],Sin[t],6((Cos[t])^2)-4 Cos[t] Sin[t]+3((Sin[t])^2)},{t,0,2 Pi,(Pi/64)}]]}],PlotRange->{{-2,2},{-2,2},{0,8}},BoxRatios->{1,1,4/2}]